通用的橡胶密封制品在国防，化工，煤炭，石油，冶金，交通运输和机械制造工业等方面的应用越来越广泛，已成为各种行业中的基础件和配件。
橡胶材料属于大变形材料，在ANSYS中怎么分析呢？材料本构模型怎么选取？橡胶密封涉及到的接触非线性问题，又该怎么创建呢?
一、问题描述
一个长的橡胶圆柱，被上下两块刚性平板夹持，使橡胶圆柱产生向下压缩位移δmax。计算力—变形响应情况。橡胶弹性模量2.82 MPa，泊松比μ=0.49967；橡胶Mooney-Rivlin常数C10=0.293 MPa，C01=0.177 MPa；橡胶圆柱半径200mm；强制位移δmax=200 mm。根据模型的对称性，取1/4结构进行研究。
图1 力学模型示意图
问题分析：橡胶材料目前广泛采用的是Mooney Rivlin本构模型，由橡胶的不可压缩性得到泊松比约为μ= 0.5。
根据弹性模量E与剪切模量G的关系式
G=E/[2(1+μ)]，
从而得E=3G。
弹性模量及剪切模量与橡胶材料常数的关系可以表示为
G=2(C10+C01)，
E=6(C10+C01)。
不可压缩参数
d=2(1-2μ)/(C10+C01)。
计算结果:压缩位移0.2m对应的载荷为1395.05N，与K-J Bathe的1400.00N基本一致，比值为0.996。
橡胶圆柱变形形状
位移-力历程曲线
橡胶圆柱位移-力计算结果
参考ANSYS Help中 VM211 Rubber Cylinder Pressed Between Two Plates
1 Determined from graphical results. See T. Tussman, K-J Bathe,"A Finite Element Formulation for Nonlinear Incompressible Elastic and Inelastic Analysis", pg. 385, fig. 6.14.
二、GUI步骤
1．进入ANSYS
程序→ ANSYS (版本号)→ ANSYS Product Launcher→ 改变working directory到指定文件夹→ 在job name输入：Rubber。
2．定义变量
Utility Menu→ Parameters→Scalar Parameters→ Selection 输入R=200→ Accept→ Selection输入C10=0.293→ Accept→ Selection输入C01=0.177→ Accept→ Selection输入EX1=6*(C10+C01) → Accept → Selection输入NU1=0.49967→ Accept→ Selection 输入DD=2*(1-2*NU1)/(C10+C01)→ Accept → Close
3．定义单元属性
(1)定义PLANE182平面应变单元
①Main Menu> Preprocessor> Element Type> Add/ Edit/ Delete→ Add→ 选择PLANE182单元，即在左列表框中选择Solid，在右列表框中选择4 NODE 182→ OK
②单元选项设置：选中PLANE182单元→ Option→ 在K3中选择Plane strain→ OK→ Close
(2)定义点-面接触单元
①定义CONTA175接触单元：Main Menu> Preprocessor> Element Type> Add/ Edit/ Delete→ Add→选择CONTA175单元，即在左列表框中选择Contact，在右列表框中选择pt-to-surf→ OK
②定义实常数：Main Menu> Preprocessor>Real Constants> Add→ Type 2→ OK→ Real Constant Set No.：2，FKN：-2000→ OK→ Close
③定义TARGE169目标单元：Main Menu> Preprocessor> Element Type> Add/ Edit/ Delete→ Add→选择TARGE169单元，即在左列表框中选择Contact，在右列表框中选择2D target169→ OK
(2)定义材料参数
①弹性模量和泊松比：Main Menu> Preprocessor> Material Props> Material Models→ Structural→ Linear→ Elastic→ Isotropic→ EX输入EX1，PRXY输入NU1，见图2→ OK
图2 橡胶材料弹性模量和泊松比
②Mooney-Rivlin超弹性材料：见图3→ 见图4→ OK
图3 超弹性Mooney-Rivlin材料
图4 橡胶Mooney-Rivlin超弹性材料参数
4．建立几何模型
(1)将当前活动坐标系转换到柱坐标系：Utility Menu> WorkPlane> change Active CS to > Global Cylindical。
(2)生成关键点：Main Menu> Preprocessor>Modeling> Create> Keypoints> In Active CS→ 依次输入关键点的坐标：1(0,0,0)，2(R,-90,0)，3(R,0,0)，4*R,-90,0)，5*R,-45,0)，6*R,0,0)，7(R,-45,0)→ OK
(3)创建圆弧线：Main Menu> Preprocessor>Modeling> Create> Lines> Lines> In Active Coord→ 依次拾取2和7，7和3→ OK
(4)将当前活动坐标系转换到直角坐标系：Utility Menu> WorkPlane> Change Active CS to> GlobalCartesian
(5)由关键点生成面：Main Menu> Preprocessor>Modeling> Create> Areas> Arbitrary> Through KPs→ 依次拾取关键点2、7、5、4→ Apply→ 依次拾取关键点7、3、6、5→ Apply→依次拾取关键点4、5、6、1→ OK
(6)打开面编号：Utility Menu> PlotCtrls>Numbering→ 勾选AREA→ OK。
5．划分网格
(1)设置单元份数：：Main Menu> Preprocessor>Meshing> Mesh Tool→ 在Size Controls下方选择Global Set→ NDIV中输入4→ OK
(2)划分面网格：Main Menu> Preprocessor> Meshing> MeshTool> Areas> Free→ Pick ALL。
(3)几何模型及面网格见图5。
图5 几何模型和面网格
5．创建目标单元
(1)创建节点：Main Menu > Preprocessor >Create > Nodes> In Active CS→ NODE输入1001，XYZ输入-2*R,-R,0→ Apply→ NODE输入1002，XYZ输入2*R,-R,0
(2)选择节点：Utility Menu> Select> Entities→从上往下依次选择Nodes,By Num/Pick, From Full→ OK→ 拾取节点1001和1002→ OK→ 屏幕窗口点击鼠标右键→ Replot
(3)指定单元属性编号：Main Menu> Preprocessor>Modeling> Create> Elements> Elem Attributes → [type]：3，[REAL]：2
(4)生成目标单元：Main Menu> Preprocessor>Modeling> Create> Elements> Auto Numbered> Thru Nodes→ 拾取节点1002和1001→ OK
注意节点的连接顺序，刚柔接触中目标刚性单元的外法线与接触单元接触。
6．位移边界条件
(1)固定目标面：Main Menu> Preprocessor>Loads> Define Loads> Apply > Structural> Displacement > On Nodes → Pick ALL→ Lab2：ALL DOF→ OK
(2) 约束左端节点UX自由度
①选择左端节点：Utility Menu> Select> Entities→ 从上往下依次选择Nodes, By Location, X coordinates, Min,Max中输入0, From Full→ Apply→ Replot→OK
②约束UX自由度：Main Menu>Preprocessor> Loads> Define Loads> Apply > Structural> Displacement > On Nodes→ Pick ALL→ → Lab2：UX→ OK
(3)耦合上端节点UY自由度
①选择上端节点：Utility Menu> Select> Entities→ 从上往下依次选择Nodes, By Location, Y coordinates, MinMax中输入0, From Full→ Apply→ Replot→OK
②耦合自由度：Main Menu> Preprocessor> Coupling / Ceqn> Couple DOFs→ PickALL→ NSET输入1，Lab选择UY→ OK，见图6
图6 耦合自由度对话框
7．提取当前选中节点的最小节点编号
(1)打开节点编号：Utility Menu> PlotCtrls>Numbering→ 勾选NODE→ OK。
(2)提取最小节点号：Utility Menu> Parameters>Get Scalar Data→ Name中输入NCEN，Node number N空着，见图7→ OK
图7 提取节点信息对话框
(3)Utility Menu→ Parameters→Scalar Parameters，查看变量NCEN的值→ Close。
(4)关闭节点编号：Utility Menu> PlotCtrls>Numbering→ 不勾选NODE→ OK。
(5)选择所有：Utility Menu> Select> Everything→屏幕窗口点击鼠标右键→ Replot。
8．创建接触单元
(1)将当前活动坐标系转换到柱坐标系：Utility Menu> WorkPlane> change Active CS to > Global Cylindical。
(2)选择单元类型1：Utility Menu> Select> Entities→从上往下依次选择Element, By Attributes, Elem type num, MinMaxInc中输入1, From Full→ Apply→ Replot→ OK。
(3)单元依附到节点上：Utility Menu> Select>Entities→ 从上往下依次选择Node, Attachedto, Element→ From Full→ Apply→ Replot→ OK。
(4)选择圆周上的节点：Utility Menu> Select>Entities→ 从上往下依次选择Nodes,By Location, X coordinates, MinMaxInc中输入半径R, Reselect→ Apply→ Replot→ OK。
(5)指定单元属性编号：Main Menu> Preprocessor>Modeling> Create> Elements> Elem Attributes → [type]：2，[REAL]：2
(6)节点表面生成接触单元Main Menu> Preprocessor>Modeling> Create> Elements> Surf / Contact> Node to Surf→ OK→ Pick ALL。
(7)选择所有：Utility Menu> Select> Everything→屏幕窗口点击鼠标右键→ Replot。
(8)坐标系转换到直角坐标系：Utility Menu> WorkPlane> Change Active CS to> Global Cartesian。
(9)有限元模型见图8。
图8 有限元模型
9．求解设置
(1)进去求解器：Main Menu> Solution。
(2)设置分析类型：Main Menu> Preprocessor>Loads> Analysis Type> New Analysis→ Static→ OK。
(3)求解控制：Main Menu> Solution>Analysis Type> Sol’n Controls。
① Basic：Analysis Options→ 选择大变形Large Displacement Static； Number of substeps输入子步数6；在输出频率Frequency中选择Write every Nth substep，where N=输入1，见图9(1)
(1) Basic选项
(2) Nonlinear选项
图9 求解控制
②Nonlinear：设置非线性收敛准则Set convergence Criteria，见图9(2)→ Replace，见图10(1)→ MINREF中输入-1，见图10(2)→ OK→ Close→ OK。
图10 非线性收敛准则
10．施加强制位移
Main Menu> Solution> Define Loads> Apply> Structural>Displacement> On Nodes→ 单选Min, Max, Inc，输入变量名NCEN→ OK→ Lab2中选择UY，VALUE中输入-100
11．求解
(1) 保存求解前文件：Utility Menu> Files> Saveas→ 输入Rubber_Load.db→ OK。
(2) 求解：Main Menu> Solution>Solve> Current LS→ File> Close→ Solve Current Load Step→ OK → Solution is done→ Close。
(3) 保存求解后文件：Utility Menu> Files> Saveas→ 输入Rubber_Solve.db→ OK。
12．通用后处理器
(1)进入通用后处理Main Menu> GeneralPostproc。
(2)设置位移比列：Utility Menu> PlotCtrls> Style> Displacement Scaling→ DMULT单选1.0→ OK。
(3)显示变形形状：Main Menu> GeneralPostproc> Plot Results> Deformed Shape→ Def+undeformed → OK，见图11。
图11 橡胶圆柱变形形状
13．时间历程后处理器
(1)进入时间历程后处理：Main Menu> TimeHistPostpro。
(2)关闭时间历程变量对话框Time History Variables。
(2)给X轴Y轴命名：Utility Menu> PlotCtrls>Style> Graphs> Modify Axes→ [/AXLAB] X-axis label中输入FORCE，[/AXLAB] Y-axislabel中输入DISPLACEMENT，见图12→ OK。
图12 曲线显示坐标轴修改
(3)定义时间历程变量：Main Menu> TimeHistPostpro> Define Variables
①→ Add，见图13→ 单选Nodal DOF result，见图14→ OK→ 单选Min, Max, Inc，输入变量名NCEN→ OK→ 选中UY→ OK
图13 定义时间历程变量
图14 变量类型
②→ Add→ 单选Reactionforces→ OK→ 单选Min, Max,Inc，输入变量名NCEN→ OK→选中FY→ OK→ Close。变量1默认为时间(本例为载荷子步)，变量2为Y方向位移，变量3为Y方向的约束反力。
(4)时间变量运算：Main Menu> TimeHistPostpro> Math Operations> Multiply→ 见图15，IR输入2，FACTA输入-2，IA输入2→ Apply→ IR输入3，FACTA输入-2，IA输入3→ OK
图15 时间变量运算
(5)打开时间历程变量对话框Time HistoryVariables：Main Menu> TimeHist Postpro> Variable Viewer→ X轴改成时间历程变量2，见图16
图16 时间历程变量对话框
(6)画位移-力历程曲线：Main Menu> TimeHist Postpro> Variable Viewer→ 单选时间历程变量3→ ，曲线见图17。
图17 位移-力历程曲线
(7)列表显示位移-力数据：Main Menu> TimeHist Postpro> Variable Viewer→ 选中变量2和3→ ，结果见图18→ 保存数据File> Save as→ 命名为xxx.txt，后缀.txt便于用记事本打开查看。
图18 橡胶圆柱位移-力计算结果
(8)提取时间点的力到变量
①Utility Menu> Parameters> Get Scalar Data→ 左右分别选择Results data和Time-hist var’s，见图19→ OK→ Name输入变量F1，Variable number输入3，Data to beretrieved选中Real val@time，Time or Locatione number输入0.5，见图20→ Apply→ OK→ 将F1改成F2，0.5改成1.0→ OK。
图19 提取变量数据
图20 从时间历程变量中提取数据
②查看提取值：Utility Menu→ Parameters→ Scalar Parameters→ 查看浏览→ Close。
三、ADPL步骤
R = 200 !橡胶圆柱半径，mm
C10 = 0.293 !超弹性材料常数
C01 = 0.177 !超弹性材料常数
EX1=6*(C10+C01) !弹性模量
NU1 = 0.49967 !泊松比
DD = 2*(1-2*NU1)/(C10+C01) !不可压缩参数
/PREP7 !进入前处理器
SMRT,OFF !关闭智能网格划分
ET,1,PLANE182, , ,2 !平面单元
KEYOPT,1,6,1 !平面应变
ET,2,CONTA175 !2-D节点-面接触单元
R,2, , ,-2000 !设置接触表面刚度
ET,3,TARGE169 !2-D目标单元
MP,EX,1, EX1 !弹性模量[MPa]
MP,NUXY,1,NU1 !泊松比
TB,HYPER,1,1,2,MOONEY !橡胶超弹性材料
TBDATA,1,C10,C01,DD
CSYS,1 !柱坐标系
K,1,0,0,0 !定义关键点，(R,θ,Z)
K,2,R,-90,0
K,3,R,0,0
K,4,0.5*R,-90,0
K,5,0.6*R,-45,0
K,6,0.5*R,0,0
K,7,R,-45,0
L,2,7 !在柱坐标系中创建圆弧线
L,7,3
CSYS,0 !直角坐标系
A,2,7,5,4 !由关键点生成面
A,7,3,6,5
A,4,5,6,1
ESIZE,,4 !整体单元份数
AMESH,ALL !面分网
N,1001,(-2*R),-R !目标面节点
N,1002,(2*R) ,-R
NSEL,S,NODE,,1001,1002 !选择目标面节点
TYPE,3 !指定单元类型
REAL,2 !指定实常数
TSHAP,LINE !设置目标面形状为线
E,1002,1001 !生成刚性目标面
D,ALL,ALL,0 !固定目标面
NSEL,S,LOC,X !选择左端节点
D,ALL,UX !约束UX自由度
NSEL,S,LOC,Y !选择上端节点
CP,1,UY,ALL !耦合UY
!提取当前节点的最小节点号NCEN
*GET,NCEN,NODE,,NUM,MIN
NSEL,ALL !选择所有节点
CSYS,1 !柱坐标系
ESEL,S,TYPE,,1 !选择单元类型1
NSLE !节点依附到单元
NSEL,R,LOC,X,R !选择半径为R的节点
TYPE,2 !指定单元类型
REAL,2 !指定实常数
ESURF !在圆周节点表面生成接触单元
ALLSEL,ALL !选择所有
CSYS,0 !直角坐标系
FINISH
/SOLU !进入求解器
ANTYPE,STATIC !分析类型为静力分析
CNVTOL,F,,,,-1 !收敛准则
NLGEOM,ON !打开大变形
NSUBST,6 !设置6个载荷子步
OUTRES,,1 !输出每个子步的结果
D,NCEN,UY,-100 !耦合节点施加强制位移
SOLVE !求解
FINISH
/POST1 !进入通用后处理器
/DSCALE,1,1 !变形比例1:1
PLDISP,1 !画变形形状
FINISH
/POST26 !进入时间历程后处理器
/AXLAB,Y,FORCE !X轴名称
/AXLAB,X,DISPLACEMENT !Y轴名称
!定义时间变量2，节点NCEN的UY位移
NSOL,2,NCEN,U,Y
! 定义时间变量3，节点NCEN的FY约束反力
RFORCE,3,NCEN,F,Y
PROD,2,2,,,,,,-2 !时间变量2的值乘以-2
PROD,3,3,,,,,,-2 !时间变量3的值乘以-2
XVAR,2 !指定X轴为位移
PLVAR,3 !画位移-力曲线
PRVAR,2,3 !列表显示位移-力的值
*GET,F1,VARI,3,RTIME,.5 !提取0.5时刻的力
*GET,F2,VARI,3,RTIME,1.0 !提取1.0时刻的力
FINISH
来源：本文由技术邻平台采集自ANSYS学习与应用公众号，版权归作者所有
注：注：如果在学习或实操的过程中有什么疑问，或者遇到无法攻克的难点，欢迎来技术邻官网的问答频道提问，众多专家第一时间为你解答。